VBA FileLen 関数 ファイルのサイズをバイト単位で返す

'■FileLen関数使用例１（エラーハンドリング付き）
Sub FileLen_Sample01()
    Dim filePath As String
    Dim fileSize As Long
 
    ' エラーハンドリングを開始
    On Error GoTo ErrorHandler
    
    ' 対象のファイルパスを指定
    filePath = "C:\VBA_test\bas\Module1.bas"
    ' FileDateTime関数でファイルの最終更新日時を取得
    fileSize = FileLen(filePath)
    ' 取得した日時情報を表示
    MsgBox "ファイルのサイズは: " & fileSize & " bytes."

    Exit Sub
ErrorHandler:
    MsgBox "実行時エラー '" & Err.Number & "': " & vbCrLf & _
           Err.Description, vbCritical, "FileLen_Sample Error"
End Sub

'■FileLen関数使用例２（Dir関数でフォルダ内一括取得する例）
Sub FileLen_Sample02()
    Dim folderPath As String, fileName As String
    Dim fileSize As Long, totalSize As Long
    Dim str As String
    
    ' エラーハンドリングを開始
    On Error GoTo ErrorHandler
    
    ' 対象フォルダのパスを設定
    folderPath = "C:\VBA_test\bas\"
    ' Dir関数で最初のファイル名を取得
    fileName = Dir(folderPath & "*.*")
    ' フォルダ内の全ファイル数回ループ処理
    Do While fileName <> ""
        ' ファイルサイズを取得
        fileSize = FileLen(folderPath & fileName)
        ' サイズを合計する
        totalSize = totalSize + fileSize
        ' ファイル名とサイズを保存
        str = str & fileName & " is " & _
            Format(fileSize, "#,###") & " bytes." & vbCrLf
        ' Dir関数で次のファイル名を取得
        fileName = Dir()
    Loop
    ' 取得できた情報を表示
    MsgBox str & "Total size of all files: " & _
                Format(totalSize, "#,###") & " bytes."
                
    Exit Sub
ErrorHandler:
    MsgBox "実行時エラー '" & Err.Number & "': " & vbCrLf & _
           Err.Description, vbCritical, "FileLen_Sample Error"
End Sub